{ stdenv
, lib
, fetchgit
, fetchFromGitHub
, installShellFiles
, libftdi1
, libusb1
, pciutils
, pkg-config

# use google's out-of-tree flashrom which can manipulate the
# write-protection registers of the chromebooks' on-board flash
# chips and can also write to the embedded controller (EC) flash,
# which is a separate chip
, forChromebook ? false

, writeProtectSupport ? true
, overlappingFmapRegionSupport ? false
}:

stdenv.mkDerivation {
  pname = "flashrom${lib.optionalString forChromebook "-chromebook"}";
  version = if !forChromebook then "1.2+wp" else "0.9.9+d2da98-google";

  src =
    if !forChromebook
    then fetchFromGitHub {
      owner = "flashrom";
      repo = "flashrom";
      rev = "cd9b7b427d19e591c1091cb783a51951ef3aeffc";
      sha256 = "sha256-gK/z+WkEHFmT/dYnNLMn4Cb2ESBfqipc19ZVxmaZabQ=";
    } else fetchgit {
      url = "https://chromium.googlesource.com/chromiumos/third_party/flashrom";
      rev = "d2da987986cf2b7f048174ba339907cc760b1c3d";
      hash = "sha256-nB8B0MXjVpAsg4+0VvO5jqRBsmEHdllgIMkTmaBJ6gE=";
    };

  nativeBuildInputs = [ pkg-config installShellFiles ];
  buildInputs = lib.optional (!stdenv.hostPlatform.isStatic) libftdi1
                ++ [ libusb1 pciutils ];

  patches = lib.optionals (writeProtectSupport && !forChromebook) [
    # the forChromebook fork already has (Google's version of) the enableWriteProtect patches
    ./0001-implement-wp-enable-disable-for-gigadevice-flash-chi.patch
  ] ++ lib.optionals forChromebook [
    ../../platform/kevin/chromebook-flashrom-kludges.patch
  ] ++ lib.optionals overlappingFmapRegionSupport [
    ./0002-layout.c-allow-nested-regions.patch
  ];

  makeFlags = if !forChromebook then [
    "PREFIX=$(out)" "libinstall"
  ] else [
    "PREFIX=$(out)"
  ];

  postInstall = lib.optionalString forChromebook ''
    mv $out/sbin/flashrom $out/sbin/flashrom-chromebook
  '';

  passthru = {
    inherit forChromebook writeProtectSupport overlappingFmapRegionSupport;
  };

  meta = with lib; {
    homepage = "https://www.flashrom.org";
    description = "Utility for reading, writing, erasing and verifying flash ROM chips";
    license = licenses.gpl2;
  };
}