You cannot select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
91 lines
3.4 KiB
Nix
91 lines
3.4 KiB
Nix
{ lib
|
|
, common_amd64
|
|
}:
|
|
|
|
{
|
|
overlays = common_amd64.overlays ++ [(final: prev:
|
|
let
|
|
fmap-size-in-bytes = 1024;
|
|
flash-chip-bytes-per-image = final.flash-chip-size-in-bytes / final.images-per-flash-chip;
|
|
cbfs-size-in-bytes = flash-chip-bytes-per-image - fmap-size-in-bytes;
|
|
fallback-image-address-in-bytes =
|
|
if final.images-per-flash-chip <= 1
|
|
then 0
|
|
else flash-chip-bytes-per-image;
|
|
in {
|
|
|
|
platform_name = "am1i";
|
|
|
|
kernel =
|
|
final.lib.makeOverridable (prev.kernel.override {
|
|
config = ./linux.config;
|
|
buildTargets = [ "bzImage" ];
|
|
}).overrideAttrs (a: {
|
|
postInstall = (a.postInstall or "") + ''
|
|
cp arch/x86_64/boot/bzImage $out/
|
|
'';
|
|
});
|
|
|
|
console-device = "ttyS1";
|
|
payload = "${final.kernel}/bzImage";
|
|
fmap = final.nixpkgsOnBuildForBuild.writeText "custom.fmap" (''
|
|
#
|
|
# Note: on x86 platforms the SPI flash is mapped into or copied into
|
|
# the topmost X bytes of memory, and the very topmost word of memory
|
|
# is the "reset vector" which points to the BIOS entry point. Because
|
|
# of this we must protect the TOPMOST half of memory; if an attacker
|
|
# controls the reset vector and any other chunk of the flash, the game
|
|
# is over.
|
|
#
|
|
FLASH@0 0x${lib.toHexString final.flash-chip-size-in-bytes} {
|
|
BIOS@0 0x${lib.toHexString final.flash-chip-size-in-bytes} {
|
|
'' + lib.optionalString (final.images-per-flash-chip > 1) ''
|
|
# read-write zone
|
|
NORMAL(CBFS) @ 0x${lib.toHexString fmap-size-in-bytes} 0x${lib.toHexString cbfs-size-in-bytes}
|
|
'' + ''
|
|
|
|
'' + lib.optionalString (final.images-per-flash-chip > 1) ''
|
|
# read-only zone (eventually)
|
|
FMAP @ 0x${lib.toHexString flash-chip-bytes-per-image} 0x${lib.toHexString fmap-size-in-bytes}
|
|
FALLBACK(CBFS) @ 0x${lib.toHexString (flash-chip-bytes-per-image + fmap-size-in-bytes)} 0x${lib.toHexString cbfs-size-in-bytes}
|
|
'' + ''
|
|
}
|
|
}
|
|
'');
|
|
|
|
coreboot = (prev.coreboot.override {
|
|
iasl = final.iasl_20180531;
|
|
coreboot-toolchain = with final.coreboot-toolchain; [ x64 i386 ];
|
|
config = with lib.kernel; {
|
|
CBFS_PREFIX = lib.mkForce (freeform "prefix");
|
|
|
|
VENDOR_ASUS = lib.mkForce yes;
|
|
BOARD_ASUS_AM1I_A = lib.mkForce yes;
|
|
|
|
CONSOLE_CBMEM = lib.mkForce no;
|
|
DRIVERS_INTEL_WIFI = lib.mkForce no;
|
|
HUDSON_XHCI_ENABLE = lib.mkForce no;
|
|
ON_DEVICE_ROM_LOAD = lib.mkForce no;
|
|
POST_DEVICE = lib.mkForce no;
|
|
POST_IO = lib.mkForce no;
|
|
|
|
DEFAULT_CONSOLE_LOGLEVEL = lib.mkForce (freeform "7");
|
|
ONBOARD_VGA_IS_PRIMARY = lib.mkForce yes;
|
|
|
|
MAINBOARD_SMBIOS_MANUFACTURER = lib.mkForce (freeform "ASUS");
|
|
MAINBOARD_SMBIOS_PRODUCT_NAME = lib.mkForce (freeform "AM1I-A");
|
|
};
|
|
uart-for-console =
|
|
if final.console-device == "ttyS0" then 0 # IDC ribbon-cable header on the motherboarod
|
|
else if final.console-device == "ttyS1" then 1 # DB9 connector on rear I/O panel; omitted from some board variants
|
|
else if final.console-device == null then null
|
|
else throw "am1i currently supports only `null` and `ttyS{0,1}` for `console-device`";
|
|
}).overrideAttrs (a: {
|
|
postInstall = (a.postInstall or "") + ''
|
|
cp src/mainboard/asus/am1i-a/cmos.layout $out/
|
|
'';
|
|
});
|
|
})];
|
|
}
|
|
|